AutoSave für RagTime

Wegen der fehlenden Möglichkeit, in RagTime mehr als einen Schritt rückgängig zu machen, wurden in diesem Forum schon verschiedene Lösungen vorgeschlagen. Eine solche Lösung war, in regelmässigen Abständen, z.B. alle 5 Minuten, automatisch eine Kopie des aktuell bearbeiteten Dokuments – der Name mit "Zeitstempel" ergänzt – abzulegen. Ich konnte mich für diese Lösung nie begeistern und habe bei mir ein "AutoSave" installiert, das alle 5 Minuten fragt, ob gesichert werden soll. Wenn ich bestätige, wird das Dokument gesichert. Wenn ich gerade daran bin, einen längeren Fliesstext in einem Rechenblatt einzutippen lehne ich jeweils ab. Wichtig; das Script muss als Programm gesichert und in den Einstellungen in die Liste der Startup-Items aufgenommen werden.
___

property saveTime : 300 -- number of seconds between executing a save

-- the idle handler is called each time after "saveTime"
on idle
	try
		tell application "System Events" to set RTinFront to (frontmost of (process 1 whose bundle identifier is "de.ragtime.ragtime"))
	on error
		-- RagTime is not open
		return saveTime
	end try
	if RTinFront then
		try
			tell application "RagTime 7" to set docName to name of document 1
		on error
			-- there is no open document
			return saveTime
		end try
		tell application "RagTime 7" to tell document docName to set isModified to modified
		if isModified then
			activate
			beep
			try
				set SaveOK to display alert "Sichern?" buttons {"Nein", "Ja"} cancel button 1
				if button returned of SaveOK = "Ja" then
					tell application "RagTime 7" to tell document docName to save
				end if
			on error
				-- just to allow ESC key for "Nein" button
			end try
			tell application "RagTime 7" to activate
		end if
	end if
	return saveTime
end idle 

___
Beschreibung:
Dieses Skript muss im "Skript-Editor" als "Programm" gesichert werden.
Die Option "Nach run-Handler anzeigen" muss eingeschaltet sein
Bei laufendem RagTime wird im vorgegebenen Intervall – sofern das zuvorderst liegende Dokument seit dem letzten Sichern modifiziert wurde – gefragt, ob gesichert werden soll. Dieses Vorgehen vermeidet das Risiko, den bestehenden Inhalt einer Rechenblattzelle mit der nächsten Tastatureingabe nach einem automatischen Sichern zu verlieren.
___

Diese Lösung ist also eher eine Erinnerung daran, wass wieder mal gesichert werden sollte, wobei durch Quittieren (mit Return oder Enter) das Sichern sofort ausgelöst wird.

Gruss, Thomas

AutoBackUp für RagTime

#14024 On 14 November, 2026 09:52 Milchmeyer said,

Die Funktion eines mehrfachen „Zurück“-Befehl ist bei RagTime technisch nicht möglich.
Daher besteht seit Jahren bei den Anwendern der Wunsch nach einer Lösung. Bereits in 2006 wurde daher eine Funktion des mehrfachen Sicherns als Idee entwickelt und durch Ole Saalmann als Script zur Verfügung gestellt und letztendlich durch Thomas Eckert für RagTime 6 in 2016 angepasst und 2018 und 2020 aktualisiert.
Diese Fassung habe ich ein wenig umgeschrieben. Dabei habe ich auch den Gedanken von Thomas Kaegi aufgegriffen, dass es mühselig ist, nicht mehr benötigte Dateien regelmäßig löschen zu müssen.
Jetzt ist eine Lösung entstanden, mit der in regelmäßigen Abständen Backups geschrieben und wieder gelöscht werden. Diese Lösung ist somit ein automatisches BackUp, kann jedoch auch geöffnete Dokumente automatisch sichern.
In den Einstellungen kann dabei festgelegt werden, welche Aufgaben abgearbeitet werden sollen.

Das Script unterstützt beim Arbeiten mit RagTime dadurch, dass in einem festen Rhythmus (voreingestellt sind 300 Sekunden) jedes geöffnete RagTimedokument in einem festgelegte Backupordner gesichert wird. Dabei wird jedesmal eine weitere Kopie geschrieben. Auch neue, noch nicht gesicherte Dokumente werden in diesen Backupordner geschrieben.
Diese Funktionalität besteht nur, solange RagTime im Vordergrund ist. Es werden somit nicht fortlaufend weitere Dateikopien erzeugt, wenn man gerade nicht mit RagTime arbeitet, das Programm jedoch im Hintergrund noch geöffnet ist.
Wenn man sich vertan hat, RagTime abgestürzt ist (was ja eher selten der Fall ist) oder man sein gerade noch offenes Dokument ohne zu sichern geschlossen hat, liegen die vorherigen Versionen im Backupordner. Dadurch kann man auf die vorherigen Arbeitsstände bei Bedarf zurückgreifen. Im Ergebnis erhält man viele Dateien im Backupordner, die man später nicht mehr braucht. Dafür prüft das Script beim Starten und danach täglich, ob es ältere Dokumente im Backupordner gibt, die dann ersatzlos gelöscht werden. (Voreingestellt ist dafür das Prüfen zu 09:00 oder später darauf, ob Dokumente, die älter als zwei Tage sind, im Backupordner vorhanden sind. Falls dies der Fall ist, werden diese in den Papierkorb verschoben)

Das Sichern im Hintergrund stört nicht beim Arbeiten, man bleibt somit zum Beispiel bei der Texteingabe auch in einer Rechenblattzelle. Bei größeren Dokumenten merkt man jedoch, dass die Sicherung erfolgt, durch einen kleinen Hänger beim Arbeiten. Ich nutze daher dieses script bislang in zwei Versionen mit unterschiedlich langen Sicherungsabständen. Je nach Aufgabe nutze ich mal das eine, mal das andere script.
Längeres Zeitintervall = weniger Sicherheit, aber auch weniger „kurze Hänger“ durch die automatische Sicherung. Für mich sind inzwischen die 300 Sekunden der Voreinstellung ein guter Mittelweg zwischen Sicherheit (man verliert maximal 5 Minuten Arbeit) und Anzahl nicht benötigter Zwischenkopien.

Vorbereitung 1)
Um das Script nutzen zu können, ist es erforderlich, einen Backupordner anzulegen, in den dann die Kopien gesichert werden. Voreingestellt ist im Script dafür der Pfad: "/Users/USERNAME/Documents/RagTime/backups/". Dabei ist dann „USERNAME“ durch den tatsächlichen Namen des Benutzerordners zu ersetzen und ein Ordner „RagTime“ im Dokumenteordner des Benutzers anzulegen. In diesem RagTime- Ordner ist ein „backups“ - Ordner anzulegen. Natürlich kann der Ordner anders benannt und woanders angelegt werden. Der Pfad ist dann entsprechend unter „property backupPath“ im Script anzugeben.

Vorbereitung 2)
Das Script kopieren und im Scripteditor in einem neuen Dokument einsetzen.
Die Einstellungen im Script nach Bedarf anpassen unter:

- property saveTime : 300 (Sekunden zwischen den Sicherungen)

- property saveCopy : 1 (bei jedem n-ten Mal eine Kopie im Backup-Ordner, sonst normal sichern (1 = immer Kopie))

- property keepDays : 2 (Nach dieser Anzahl in Tagen kommen Backups, die älter sind, in den Papierkorb (0 = alle))

- property cleanupHour : 9 (Uhrzeit als volle Stunde, ab der täglich einmal aufgeräumt wird)

Vorbereitung 3)
Das Script im Scripteditor als „APP“ speichern und dabei den Haken setzen für die Option „Programm nach Run-Handler geöffnet lassen"

Das Script habe ich im oben genannten RagTime-Ordner im Dokumente Ordner abgelegt und bei den Anmeldeobjekten eingetragen, so dass es immer aktiv ist.

Bislang macht es bei mir seit einer Woche, was es soll.

Mit freundlichem Gruß
Mathias Milchmeyer

Re: AutoBackUp für RagTime (Applescript)

#14025 On 14 November, 2026 09:56 Milchmeyer said,

 
(*
Automatisches Backup mit Aufräumen für RagTime 7.5
	Basis ist das script von Thomas Eckert vom 23.08.2016
	Anpassung an RagTime 7.5, der Pfadschreibweise, Ergänzung des Löschens alter Backups
	durch Mathias Milchmeyer, Stand 14.11.2026
	Dieses Skript muss im "Skript-Editor" als "Programm" gesichert werden.
	Die Option "Programm nach Run-Handler geöffnet lassen" muss eingeschaltet sein.
	Nach dem ersten Start müssen mehrmals Rechte für den Zugriff erlaubt werden
	Vorbereitung: im Dokumenteordner ist ein neuer Ordner „RagTime“ 
	und darin ein Ordner „backups“ anzulegen. 
	Im script ist der Benutzername unter „property backupPath“ 
	an Stelle von „USERNAME“ einzusetzen

	- Beim Start: Dateien im Backup-Ordner, die älter als keepDays Tage sind,
	  kommen in den Papierkorb.
	- Danach einmal täglich nach cleanupHour Uhr (09:00) dasselbe. War der Mac zu dieser
	  Zeit im Ruhezustand, wird das Aufräumen nach dem Aufwachen nachgeholt.
	- Alle saveTime Sekunden: geänderte RagTime-Dokumente sichern
	  (bei jedem saveCopy-ten Mal als Kopie im Backup-Ordner).
*)
property saveTime : 300 -- Sekunden zwischen den Sicherungen
property saveCopy : 1 -- bei jedem n-ten Mal eine Kopie im Backup-Ordner, sonst normal sichern (1 = immer Kopie)
property saveCounter : 0
property keepDays : 1 -- Backups, die älter sind, kommen in den Papierkorb (0 = alle)
property cleanupHour : 9 -- Uhrzeit (volle Stunde), ab der täglich aufgeräumt wird
property tickTime : 30 -- Prüftakt in Sekunden

-- Backup-Ordner: normaler Text mit "/", muss mit "/" enden, Ordner muss existieren
property backupPath : "/Users/USERNAME/Documents/RagTime/backups/"

property nextSave : missing value
property nextCleanup : missing value

-- ---------- Start ----------
on run
	cleanupBackups()
	set nextCleanup to nextCleanupTime()
	set nextSave to (current date) + saveTime
end run

-- ---------- Hilfsfunktionen ----------
-- nächster Aufräumzeitpunkt: heute cleanupHour Uhr, falls das noch bevorsteht, sonst morgen
on nextCleanupTime()
	set d to current date
	set time of d to cleanupHour * hours
	if d ≤ (current date) then set d to d + days
	return d
end nextCleanupTime

-- Backups älter als keepDays Tage in den Papierkorb verschieben
on cleanupBackups()
	try
		set backupFolder to POSIX file backupPath as alias
		set cutoff to (current date) - (keepDays * days)
		tell application "Finder"
			set oldFiles to (every file of backupFolder whose modification date  0 then delete oldFiles
		end tell
	on error errMsg number errNum
		display dialog "Aufräumen-Fehler " & errNum & ": " & errMsg buttons {"OK"} default button 1 giving up after 20
	end try
end cleanupBackups

-- dateinamentauglicher Zeitstempel ohne Doppelpunkt
on dateStamp()
	set cd to current date
	set ds to year of cd as string
	set ds to ds & "-" & ((month of cd as number) as string)
	set ds to ds & "-" & ((day of cd as number) as string)
	set AppleScript's text item delimiters to {":"}
	set ts to every text item of time string of cd
	set AppleScript's text item delimiters to {""}
	set ds to ds & "-" & ts
	return ds
end dateStamp

-- neuen Dateinamen mit Datum/Zeit bilden
on getSaveName(orgName)
	set fName to orgName
	set fLen to count fName
	if fLen > 4 then
		if text (fLen - 3) thru fLen of fName is ".rtd" then set fName to text 1 thru (fLen - 4) of fName
	end if
	return fName & "-" & dateStamp() & ".rtd"
end getSaveName

-- alle geänderten RagTime-Dokumente sichern
on autoSave()
	try
		tell application "System Events" to set RTinFront to (frontmost of (process 1 whose bundle identifier is "de.ragtime.ragtime"))
	on error -- RagTime läuft nicht
		return
	end try
	if not RTinFront then return
	set docCounter to 1
	set incSaveCount to true -- Zähler nur einmal pro Durchlauf erhöhen
	repeat
		try
			tell application "RagTime 7" to set docName to name of document docCounter
		on error -- kein weiteres offenes Dokument
			return
		end try
		set saveName to getSaveName(docName)
		tell application "RagTime 7" to tell document docName to set isModified to modified
		if isModified then
			if incSaveCount then
				set saveCounter to saveCounter + 1
				set incSaveCount to false
			end if
			try
				if 0 = saveCounter mod saveCopy then
					tell application "RagTime 7" to save document docName in file (backupPath & saveName) with save a copy behavior
				else
					tell application "RagTime 7" to tell document docName to save
				end if
			on error errMsg number errNum
				display dialog "AutoSave-Fehler " & errNum & ": " & errMsg buttons {"OK"} default button 1 giving up after 20
			end try
		end if
		set docCounter to docCounter + 1
	end repeat
end autoSave

-- ---------- Idle-Handler (alle tickTime Sekunden) ----------
on idle
	if (current date) ≥ nextCleanup then
		cleanupBackups()
		set nextCleanup to nextCleanupTime()
	end if
	if (current date) ≥ nextSave then
		autoSave()
		set nextSave to (current date) + saveTime
	end if
	return tickTime
end idle

Re: AutoSave für RagTime

#14016 On 4 November, 2026 18:39 jacques villars said,

Hallo Thomas,

Ich habe dein Script installiert ; es scheint zu funktionieren, d.h. alle zwei Minuten bekomme ich den Piepton mit dem Fenster "NEIN/JA" ; ich clicke auf "JA", das Fenster schließt sich aber nichts wird gespeichert : kannst du mir sagen, wo der Fehler liegt ?

Freundliche Grüße,

jacques

Re: AutoSave für RagTime

#14017 On 5 November, 2026 11:14 Thomas Kaegi said,

Hallo Jacques

Bist du sicher? Es soll ja einfach das gerade offene Dokument gesichert werden, damit die letzten Schitte nicht verlorengehen. Der massgebende Teil des Scripts ist:

			try
				set SaveOK to display alert "Sichern?" buttons {"Nein", "Ja"} cancel button 1
				if button returned of SaveOK = "Ja" then
					tell application "RagTime 7" to tell document docName to save
				end if
			on error

Wenn du die Texte nicht übersetzt hast, sollte es wirklich so funktionieren. Die erste Zeile im "try" definiert den Knopf mit den Texten "Nein" und "Ja". Zweite Zeile: Wenn der Ja-Knopf gedrückt oder die Return- oder Enter-Taste betätigt wurden, wird die dritte Zeile ausgeführt und da wird einfach der "Dokument Sichern"-Befehl gegeben. Ich sehe keine mögliche Erklärung dafür, dass es nicht funktionieren sollte.

Cordialement
Thomas

Re: AutoSave für RagTime

#14018 On 5 November, 2026 16:38 jacques villars said,

Bonjour Thomas,

Habe ich Tomaten auf den Augen? (wie man auf Deutsch sagt, oder?) Diese Frage hätte ich nicht stellen sollen, ich hätte einfach besser aufpassen müssen; in der Übersetzung des Skripts hatte ich hier "oui" und da noch "Ja" !

Nun stimmt es. Ich habe trotzdem mehr als eine Stunde mit Versuchen verloren. Entschuldigung und vielendank,

bien cordialement,

jacques

Re: AutoSave für RagTime

#14011 On 31 Oktober, 2026 13:31 Milchmeyer said,

Hallo Thomas,

Du bis da deutlich besser als ich. Weder Dein AutoSave, noch das alte script von Thomas Eckert konnte ich für mich anpassen.
Danke, das ist schonmal ein kleiner Schritt und hilft bei der Arbeit.

Mit freundlichem Gruß
Mathias Milchmeyer

Re: AutoSave für RagTime

#14015 On 31 Oktober, 2026 18:40 Thomas Kaegi said,

Hallo Mathias

„Mein" Script“ ist gar nicht von mir. Ich bin kein Script-Guru und kann höchstens anzupassen versuchen, was ich irgendwo finde. Eine erste Version „meines“ AutoSave hatte Jürgen Schell geschrieben und als diese nicht mehr funktionierte hat sie Thomas Eckert wieder in Schuss gebracht. Das dürfte auch beim anderen AutoSave-Script so gewesen sein.

Ich habe „mein" Script eben nochmals angesehen und sehe keinen Grund, weshalb das in irgend einer Umgebung (damit meine ich sowohl die Konfiguration des eigenen Macs als auch die OS-Version) nicht funktionieren sollte. Nichts im Script sieht umgebungs-spezifisch aus! Das trifft auch für das andere AutoSave-Script zu! Die Anpassung des ursprünglichen Scripts durch Thomas Eckert war meines Wissens nur nötig, als Apple das Trennzeichen in der Pfad-Definition von : zu / geändert hatte.

Trotzdem die Frage: Bist du schon bei Golden Gate? Ich arbeite noch mit macOS Tahoe (26.6.2) und benütze das Script seit vielen RT- und OS-Versionen ohne Probleme. Es läuft immer im Hintergrund sobald der Mac hochgefahren ist, selbst wenn RagTime nicht läuft.

Freundliche Grüsse
Thomas

Re: AutoSave für RagTime

#14019 On 7 November, 2026 14:13 Milchmeyer said,

Hallo Thomas,

ja, ich bin hier bei "Golden Gate".
Dein script habe ich hinbekommen, da fehlte mir in der Zeile "tell application "RagTime 7.5" to activate" das "7.5".
Ich hatte hier noch die "7".

Mit freundlichem Gruß
Mathias Milchmeyer

Re: AutoSave für RagTime

#14020 On 7 November, 2026 18:14 Thomas Kaegi said,

Hallo Mathias

Ich habe eben nochmals nachgeschaut. Tatsächlich heisst es im Script drei Mal

tell application "RagTime 7""

Aber das funktioniert unter macOS Tahoe 26.6.2 ohne Probleme, obwohl ich natürlich auch mit RagTime 7.5 arbeite.

Normalerweise aktualisieren die Scripts das selbst. Aber vielleicht ist das nicht so, wenn sie als App gespeichert werden.

Gruss, Thomas

Re: AutoSave für RagTime

#14007 On 29 Oktober, 2026 10:29 Süppel said,

Ich finde diese Lösung ebenfalls einen «Murks» und bin der Meinung, dass RagTime schon lange mehrere Undo-Schritte unterstützen sollte (wenigstens 10).

Die Ein-Schritt-Rückgängig-Funktion ist für eine aktuelle App einfach nicht mehr zeitgemäss. Eigentlich ist es schon fast peinlich, dass RagTime das bis heute nicht bietet!

Re: AutoSave für RagTime

#14008 On 29 Oktober, 2026 15:04 admin said,

Hallo „Süppel“,

ich finde es – gelinde gesagt – etwas undankbar, die Lösung von Thomas Kaegi „einen «Murks»“ zu nennen! Er hat sich Gedanken und Mühe gemacht, anderen Anwendern eine Lösung anzubieten.

Zum Thema „multiple undo“:

Leider ist „multiple undo“ in RagTime technisch nicht vorgesehen und kann auch nicht nachgerüstet werden. RagTime besteht aus vielen unabhängigen Komponenten (Grafik, Rechenblätter, Textverarbeitung, Bildverarbeitung, Layouts u. a.), die jeweils eigenständig arbeiten und im Dokument zusammengeführt werden.

Bereits eine einzelne Änderung – beispielsweise die Eingabe eines Buchstabens im Layout – zieht daher eine Vielzahl von Folgeänderungen in den verschiedenen Komponenten nach sich. Deshalb steht ein einfacher Undo-Schritt zur Verfügung; mehrere Rückgängig-Schritte sind jedoch nicht möglich und lassen sich technisch nicht implementieren.

Wir bitten um Ihr Verständnis für diese technische Einschränkung. Gleichzeitig freuen wir uns, dass RagTime in vielen anderen Bereichen Stärken aufweist, die andere Programme nicht in gleichem Maße bieten.

Ihr RagTime.de-Team

Re: AutoSave für RagTime

#14012 On 31 Oktober, 2026 14:05 Milchmeyer said,

Liebes RagTime-Team,

ja, RagTime ist ein ganz besonderes Programm.
Mit der speziellen Dokumentenstruktur und dem "verzeigerten Dateiformat" ergeben sich eben Zwänge, die in anderen Programmen nicht bestehen. Aber darauf kann man doch auch programmiertechnisch reagieren.
Es wird von den Anwendern immer wieder nach der "UnDo"-Funktion gefragt, da dies in anderen Programmen einfach der Standard ist.

Wenn dies nicht möglich ist, jedoch gefragt wird, kann man doch mit Lösungen antworten, die es nur in RagTime gibt, und die dann in anderen Programmen eben nicht möglich sind. Die Stärke RagTimes liegt doch genau in der Modularität. Es gibt Ergänzungen wie die Metaformeln oder die Power-Funktionen, warum dann nicht ein Extra- AutoSave-Paket oder etwas in der Art?

(Beispiel: In ArchiCAD kann ich mir einstellen, ob eine "Schattendatei" erstellt werden soll und wie oft die Originaldatei in diese Schattendatei kopiert werden soll. Das kann nach jedem Schritt der Fall sein, aber auch nach jedem hundertsten Schritt. Wenn meine Datei 50GB groß ist und ich für maximale Sicherheit nach jedem Schritt eine Kopie erstellen lasse, dann gibt es viel Datenmüll und die "Schwuppdizität" leidet. Wenn ich nicht warten möchte, muss ich eben mehr Risiko eingehen und stelle auf 10 Schritte bis zum nächsten AutoSave.
Zusätzlich kann ich dort noch die Zahl der UnDo-Schritte einstellen.)

Eine ähnliche Strategie kann ich mir auch für RagTime vorstellen.

Warum sollte man nicht den von den Anwendern erfundenen Weg wählen und anbieten, dass RagTime in bestimmten wählbaren Intervallen ein Autosave durchführt.
Das kann z.B. alle zehn Schritte, alle fünf Minuten oder eine andere Bezugsgröße wie ein Fensterwechsel sein, die dann durch User gewählt werden kann.
Man könnte doch dabei auch festlegen, dass die jeweils älteste Kopie gelöscht wird und maximal zehn Kopien aufbewahrt werden, so dass eine "rollende" Autosave-Funktion dazu führt, dass man dann eben zehn Kopien zurückgehen kann. Wer dann zehn Undos möchte, muss eben warten, weil nach jedem Schritt das ganze Dokument einmal gesichert wird. Wenn einem das zu wenig "Schwuppdizität" ist und man nicht dauernd warten möchte, dann stellt man eben jeden zehnten Schritt oder fünf Minuten ein und kann dann auf genau diese dann erzeugten "Snapshots" zurückgreifen.
Wenn dies bereits mit Applescript möglich ist, wird es doch für die RagTime-Programmierer eher einfach sein, eine entsprechende Funktion zu implementieren.
Weiterhin gibt es dann in RagTime eben kein "UnDo", weil es eben RagTime ist.
Dafür gibt es dann jedoch viel mehr Sicherheit, weil es auf dem Laufwerk zwischengespeicherte Kopien gibt, die dann automatisch im Hintergrund angelegt werden. Wenn RagTime abgestürzt ist (wirklich eher selten), dann hilft einem eine UnDo-Funktion nicht. Aber wenn es dann noch die zwischengespeicherten "SnapShots" gibt, dann ist das deutlich mehr Sicherheit als ein "UnDo".
Dann hätten wir eine RagTime-Lösung, die mehr ist als ein UnDo und die es nur bei RagTime gibt.

Es müssten Details festgelegt werden, wie zum Beispiel, wo diese "SnapShots" liegen sollten.
Das könnte sowohl in einem zentralen backup-Ordner sein, wie es Thomas Eckert vor vielen Jahren gewählt hat.
Es könnte aber auch eine aufwändige Struktur sein, mit der RagTime zu jeder Datei parallel in der Dateistruktur einen Ordner mit gleichem Namen anlegt und darin die durch den User festgelegte Anzahl Kopien vorhält.
Wenn das bei RagTime der Standard ist, könnte dieser Ordner auch unter "Bearbeiten" unterhalb der "Widerrufen"-Funktion im Menü abrufbar sein, wo man dann seine zehn zuletzt gesicherten Zwischenstände abrufen kann.

Eine entsprechende Funktion darf dann gerne auch etwas kosten.

Liebes RagTime-Team, bitte mal darüber nachdenken, ob eine derartige Lösung irgendwie in Frage kommt.
Darüber würde nicht nur ich mich freuen, es wäre auch ein Verkaufsargument für neue Anwender, die leider oft, ohne sich überhaupt mit RagTime beschäftigen, sofort "zumachen", wenn sie hören, dass es dort nur genau einen "UnDo"-Schritt gibt.

Mit freundlichem Gruß
Mathias Milchmeyer

Re: AutoSave für RagTime

#14009 On 30 Oktober, 2026 11:07 Süppel said,

Hallo Thomas, hallo RagTime-Team

Zunächst möchte ich klarstellen, dass meine Bemerkung keineswegs als persönliche Kritik an Thomas Kaegis Lösung gemeint war. Als langjähriger RagTime-Nutzer seit Version 3 kenne ich Thomas und seine wertvollen Beiträge zum Forum sehr gut. Ich schätze es, wenn sich Anwender die Mühe machen, praktische Lösungen für bestehende Einschränkungen zu entwickeln und anderen zur Verfügung zu stellen.

Meine Kritik richtet sich an die grundsätzliche Situation. Ich bin nach wie vor der Meinung, dass eine Multi-Undo-Funktion zu den grundlegenden Funktionen einer modernen Office-Suite gehört und in RagTime schon längst hätte umgesetzt werden sollen.

Die technische Erklärung des RagTime-Teams kann ich nachvollziehen. Dennoch finde ich es bedauerlich, wenn eine essentielle Funktion aufgrund der bestehenden Architektur grundsätzlich nicht realisierbar sein soll.

Vielleicht wäre es sinnvoll, alternative Ansätze in Betracht zu ziehen. Eine automatische Sicherung mit mehreren Generationen von Dokumentversionen könnte eine Möglichkeit sein, zumindest einen Teil der fehlenden Funktionalität abzufangen. Dass Anwender bereits versucht haben, solche Lösungen selbst zu entwickeln, zeigt den entsprechenden Bedarf.

Ich finde, es sollte nicht Aufgabe der Anwender sein, sich für grundlegende Funktionen mit selbst gebastelten Workarounds behelfen zu müssen. Hier wäre RagTime selbst gefordert, eine praktikable Lösung anzubieten.

RagTime ist nach wie vor eine hervorragende und für mich unverzichtbare Office-Suite. Gerade deshalb würde ich mir wünschen, dass auch solche grundlegenden Funktionen wieder stärker in den Fokus der Weiterentwicklung rücken.

Gruss
Cyrill

Re: AutoSave für RagTime

#14010 On 31 Oktober, 2026 10:59 Thomas Kaegi said,

Hallo Cyrill

Du schreibst:
Vielleicht wäre es sinnvoll, alternative Ansätze in Betracht zu ziehen. Eine automatische Sicherung mit mehreren Generationen von Dokumentversionen könnte eine Möglichkeit sein, zumindest einen Teil der fehlenden Funktionalität abzufangen. Dass Anwender bereits versucht haben, solche Lösungen selbst zu entwickeln, zeigt den entsprechenden Bedarf.

Ich finde, es sollte nicht Aufgabe der Anwender sein, sich für grundlegende Funktionen mit selbst gebastelten Workarounds behelfen zu müssen. Hier wäre RagTime selbst gefordert, eine praktikable Lösung anzubieten.

RagTime hat durchaus eine Lösung geliefert. Siehe: http://experts.ragtime.de/experts/node/3817

Gruss, Thomas

Re: AutoSave für RagTime

#14013 On 31 Oktober, 2026 14:10 Milchmeyer said,

Hallo Thomas,

ja, das war die Version von Thomas Eckert aus 2016.
Er hatte dort für RagTime 6.6 vor zehn Jahren gezeigt, wie man einen Ansatz mit dem Sichern von Zwischenschritten realisieren kann.
Leider funktioniert diese Lösung nicht mit der aktuellen Version. Warum, weiß ich leider nicht und habe es auch trotz mehrerer Versuche nicht korrigieren können. Vermutlich hat sich zu viel bei AppleScript geändert.
Da wäre es schön gewesen, wenn RagTime dieses script aktuell hält.
Dies ist jedoch leider nicht der Fall und deshalb ein eher nicht so gutes Beispiel dafür, dass RagTime Lösungen geliefert hat.
Es war vor zehn Jahren eine Lösung, die heute nicht mehr funktioniert.

Mit freundlichem Gruß
Mathias Milchmeyer