PDF export mit RagTime 6.6

Von admin. | 4 November, 2015 - 08:37
Kurzbeschreibung:

Beispiel Droplet für den PDF export eines RagTime Dokuments

Ausführliche Beschreibung:

Wir haben eine Anfrage zum PDF export mit RagTime 6.6 bekommen. Es gibt hierzu schon einige ältere Forumeinträge und auch RagTime-Dokumente mit AppleScript zu PDF konvertieren, jedoch wird hier immer noch etwas Nachbearbeitung benötigt, was nicht für jeden Anwender hilfreich ist.

Daher habe ich nun folgendes AppleScript Droplet geschrieben:
(*
PDF export droplet, das RagTime-Dokumente zu PDF exportiert.
Das Script nimmt an, dass die Dokumente je ein Layout enthalten,
dass exportiert werden soll. (Gibt es mehrere, wird das erste exportiert.)
© 2015 Thomas Eckert, www.ragtime.de
*)

on open theItems
repeat with anItem in theItems
exportSingleFile(anItem as string)
end repeat
end open

on run
if false then
-- just for debugging: set a path which can be used via "Run Script"
exportSingleFile("Macintosh HD:Users:helios:Desktop:Mac-Diagraxmm.rtd")
else
display dialog "Drag some RagTime files on me" buttons {"Quit"} default button 1
end if
end run

on exportSingleFile(aFile)
set exportTarget to pdfName(aFile as string)
tell application "RagTime 6.6"
activate
open (aFile as alias)
set docName to name of document 1
tell application "System Events" to set shouldCreatePDF to not (exists (alias exportTarget))
if shouldCreatePDF then
try
save layout 1 of document 1 in file exportTarget converting to "Acrobat PDF" with font inclusion without settings dialog
end try
end if
try
close document 1 saving no
end try
end tell
end exportSingleFile

on pdfName(rtName)
if text ((count rtName) - 3) thru last character of rtName = ".rtd" then
set rtName to text 1 thru ((count rtName) - 4) of rtName -- remove the ".rtd" suffix
end if
return rtName & ".pdf"
end pdfName

Es nimmt ein Dokument "Beispiel" oder "Beispiel.rtd" und erzeugt daraus "Beispiel.pdf" im gleichen Verzeichnis. Falls es dort schon eine Datei "Beispiel.pdf" gibt, wird die Datei übersprungen.

Gruß,

Thomas Eckert
RagTime Support

Anhang Größe
PDFExport.applescript 1.34 KB

Aktualisierter Anhang für das Exportskript

#11977 On 12 November, 2015 07:53 admin said,

Leider hat sich gezeigt, dass OS X das Programm aus dem ZIP-Archiv nicht immer ausführt. Es kann zu einem Fehler beim starten kommen ("Programm defekt").

Daher habe ich nun noch einmal einen neuen Anhang als Text angefügt. Dieser Text muss im Apple "Script Editor" geöffnet werden. Dann neu speichern als "Programm".

Danach kann man RagTime-Dokumente zur Konvertierung darauf droppen.

Exportscript exportiert Stammlayout

#12124 On 6 April, 2016 12:20 Thomas Kaegi said,

Wie sich herausgestellt hat, wird bei Dokumenten mit Stammlayout dieses als erstes Layout angesehen. Thomas Eckert schrieb mir dazu:
--
Beim PDF_Export wird
save layout 1 of document 1 ...
ausgeführt. Also das ERSTE Layout, das RagTime im Dokument findet.
Offenbar wird in diesem Fall das Stammlayout verwendet.
Wenn Sie den PDF-Export ändern und
save layout "Layout 1" of document 1 ...
schreiben erfolgt der Export wie erwartet.

Das ist mal wieder einer der Fallstricke bei Skripten die für alles gelten sollen.
Ich denke damit können wir aber leben.
--
Im konkreten Fall wohl den Namen des Layouts gemäss Inventar, nicht einfach "Layout 1". Hier zeigt sich wieder mal, wie wichtig es wäre, in einer nächsten Version von RagTime das Layout definieren zu können, das als Vorschau im RT-Foyer und hoffentlich auch im Finder angezeigt werden soll. Das wäre dann nämlich das gleiche Layout, das auch als PDF zu exportieren wäre.

Gruss, Thomas Kaegi