Komponenten können mit der “save�-Anweisung exportiert werden. Das Vorgenen ist damit so ähnlich wie beim Sichern eines Dokuments im RagTime-eigenen Format.
Der save-Anweisung (Sie finden Sie in der Standard Suite im AppleScript-Verzeichnis) kennt eine Reihe von Optionen für den Export. Folgendes Script exportiert die Textkomponente namens “Text 1� im Word-Format:
set zielDatei to choose file name with prompt ¬
     "Wohin soll der Text exportiert werden?"
tell application "RagTime 6.5"
     save text flow "Text 1" of document 1 in zielDatei ¬
          converting to "MS-Word 6/95"
end tell
Die Export-Optionen lassen sich durch recording ermitteln. Deshalb verzichten wir hier auf eine detailiertere Darstellung.
Die Import-Optionen, z.B. welche Textkodierung benutzt werden soll, kann man steuern, wenn man zuerst die Komponente anlegt und dann mit change auf den Inhalt der Importdatei setzt:
set textDatei to choose file with prompt "Text-Datei auswählen"
tell application "RagTime 6.5"
     tell document 1
          set Textkomponente to (make new text flow at end)
          change Textkomponente to textDatei using encoding 256 without link to file
-- Encoding 256 ist Mac Roman
          set Rechenblattkomponente to (make new table at end)
          change cell "A1" of Rechenblattkomponente to textDatei using encoding 256 without link to file, value format detection and import formats
     end tell
end tell
Das Script erzeugt eine neue Textkomponente und setzt dann den Inhalt auf textDatei, gibt aber dabei bereits das Encoding vor. Die für die meisten Anwender wohl wichtigsten Encodings sind:
256: Macintosh Standard für westeuropäische Sprachen
512: Windows Standard für westeuropäische Sprachen
Encoding-Nummern finden Sie in der RagTime-Hilfe "RagTime-Formeln und -Funktionen" im Abschnitt "Hintergrundinformationen".
Es wird ein Rechenblatt angelegt und die Zelle A1 auf die Datei geändert. Da value format detection und import formats beide festgelegt sind (hier: ausgeschaltet), folgt auch dieser Dialog nicht.
Die so importierten Komponenten können mit set (“set rectangle 1 of page 1 to...�) platziert werden.
Für den Import können auch Filter festgelegt werden, besonders bei Bildern bisweilen wichtig:
...convert with "JPEG" ...
Ein Beispielscript:
set bildDatei to choose file with prompt "Bild-Datei auswählen" of type list {"JPEG"}
tell application "RagTime 6.5"
     tell document 1
          set Bildkomponente to (make new picture at end)
          change Bildkomponente to bildDatei ¬
               convert with "JPEG" without link to file
     end tell
end tell
Importe werden aufgerufen, indem man den Wert eines Objekt, das die Importdatei aufnehmen kann, auf einen alias / ein file setzt oder eine bestehende Komponente dahin umwandelt. Folgendes Script weist zunächst über einen Auswahldialog einer Variable einen alias-Wert zu und importiert dann diese Datei an verschiedenen Stellen in das aktive Dokument:
set textDatei to choose file with prompt "Text-Datei auswählen"
tell application "RagTime 6.5"
     activate
     tell document 1
          make new text flow with data textDatei at end
          -- Importiert die Datei und fügt sie als neue Textkomponente hinzu, ohne diese zu platzieren
          set Rechteck to make new rectangle with data {100, 50, 300, 500} at beginning of page 1 of layout 1
          set contents of Rechteck to textDatei
          -- Setzt die Inhaltsart des Rechtecks auf Text und importiert die Datei
          set text flow 1 to textDatei
          -- Importiert die Datei und ersetzt die erste Textkomponente durch deren Inhalt
          set insertion point after last character of text flow 1 to textDatei
          -- Importiert die Datei und hängt sie am Ende von Textkomponente 1 an
          set Rechteck to make new rectangle with data {350, 50, 550, 500} with properties {contents type:table} at beginning of page 1 of layout 1
          set cell "A1" of table 1 to textDatei
          -- Importiert die Textdatei in das Rechenblatt beginnend mit Zelle A1
     end tell
end tell
Bei dieser Technik erfolgt der Import so, wie manuell aufgerufen. Es werden also jedesmal die Dialoge gezeigt, die RagTime auch sonst zeigt: Welche Codierung der Text hat, ob beim Import in das Rechenblatt eine Werteformaterkennung erfolgen soll etc.