Pipelines sind Bestandteile des Dokuments auf oberster Ebene und nicht einzelnen Komponenten zugeordnet. Master Pipelines sind die Variante, die für Stammlayouts benutzt wird. Wiederum sind sie nicht Bestandteil des Stammlayouts sondern des Dokuments.
Angelegt werden sie mit einer Liste von Referenzen auf Container. Ein Script-Beispiel vermittelt die Struktur am besten. Angenommen wird ein Dokument mit einem Layout und diversen Seiten. Jeweils rectangle 1 auf jeder Seite soll in die Pipeline aufgenommen werden:
set rechteckListe to {}
tell application "RagTime 6.5"
     tell document 1
          tell layout 1
               repeat with n from 1 to count pages
                    copy (a reference to rectangle 1 of page n) to end of rechteckListe
               end repeat
          end tell
          set diePipeline to make new pipeline with data rechteckListe at end
     end tell
end tell
Nach der repeat-Schleife enthält rechteckListe die Referenzen auf die Rechtecke, in der make-Anweisung werden sie übergeben. Die Variable diePipeline enthält anschließend einen Wert wie
pipeline "Pipeline 1" of document id 1 of application "RagTime 6.5"
Soll die Pipeline anschließend noch im Script bearbeitet werden, muss man sich diesen Bezug unbedingt in eine Variable schreiben, man hat sonst kaum eine Chance, die Pipeline wieder anzusprechen.
Im folgenden Script erzeugen wir eine Pipeline, die abwechselnd das rectangle 1 jeder Seite mit einer vertikalen und einer horizontalen Verbindung versieht. Installiert man in dieser Pipeline ein Rechenblatt, werden die ersten Spalten auf den (linken) Seiten 2, 4, 6.. gezeigt. Die folgenden Spalten der Tabelle erscheinen auf den (rechten) Seiten 3, 5, 7...
set rechteckListe to {}
tell application "RagTime 6.5"
     tell document 1
          tell layout 1
               set seitenAnzahl to count pages
                    repeat with n from 2 to seitenAnzahl by 2
                         copy (a reference to rectangle 1 of page n) to end of rechteckListe
                    end repeat
          end tell
          set diePipeline to make new pipeline with data rechteckListe at end
          repeat with n from 1 to round ((seitenAnzahl - 1) / 2) rounding down
               set horizontal successor of pipeline element n of diePipeline to rectangle 1 of page (n * 2 + 1) of layout 1
          end repeat
     end tell
end tell
In der ersten Schleife wird die vertikale Pipeline auf mit den Rechtecken auf den geraden Seiten angelegt.
In der zweiten Schleife wird jedem Element der Pipeline ein horizontaler Nachfolger zugewiesen.
Die Eigenschaften horizontal successor, vertical successor, horizontal predecessor und vertical predecessor gehören den Objekten “pipeline element�. Mit ihnen kann eine Pipeline an bestimmten Positionen gezielt erweitert oder umgelenkt werden